IN THE NEXT LINE, REPLACE THE "#" WITH "?" AND YOU WILL GET THE CORRECT FIRST LINE OF THE FILE (THIS WAS PUT IN TO PREVENT IE FROM BEING "INTELLIGENT" AND TRYING TO PROCESS THIS FILE)
<#xml version="1.0" encoding="UTF-8"#>
<xsl:stylesheet 
	version="1.0" 
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<!--xmlns:fo="http://www.w3.org/1999/XSL/Format"-->
	

<!-- ********************************************************************
		Copyright (c) Edward Maesen, 2002, San Francisco, CA, USA. All rights reserved.
     ******************************************************************** 

		This is a secondary stylesheet for web pages,
		containing debug templates.
		
		This stylesheet is included in main.xsl


		Debug should be called as:

		<xsl:call-template name="_DEBUG">
			<xsl:with-param name="msg">message to display as part of rendered content</xsl:with-param>
			<xsl:with-param name="msg_out">message to display in external log</xsl:with-param>
		</xsl:call-template>

     ********************************************************************  
     ******************************************************************** -->


	<!-- catch any template that isn't matched anywhere else -->
	<xsl:template match="*">
		<xsl:call-template name="_DEBUG">
			<xsl:with-param name="msg_out">
				No template matches <xsl:value-of select="name(.)"/>.
			</xsl:with-param>
			<xsl:with-param name="msg">
				No template matches &lt;<xsl:value-of select="name(.)"/>&gt;
				with attributes 
				<i>
				<xsl:for-each select="@*">
					<xsl:value-of select="name(.)"/>=<xsl:value-of select="."/>
					<xsl:if test="position()!=last()">
						<xsl:text>,</xsl:text>
					</xsl:if>
					<xsl:text> </xsl:text>
				</xsl:for-each>
				</i>
				and text
				<i>"<xsl:apply-templates/>"</i>.
				&lt;/<xsl:value-of select="name(.)"/>&gt;
			</xsl:with-param>
		</xsl:call-template>
	</xsl:template>
	

	<!-- the main debug template to display a debug message -->
	<xsl:template name="_DEBUG">
		<xsl:param name="msg_out" select="''"/>
		<xsl:param name="msg" select="''"/>
		<xsl:if test="$debug">
			<xsl:if test="$msg_out!=''">
				<!-- message to external output (most likely console) -->
				<xsl:message><xsl:copy-of select="$msg_out"/></xsl:message>
			</xsl:if>
			<xsl:if test="$msg!=''">
				<!-- message to regular output file -->
				<font color="red">
					<br/>
					<xsl:text> #[ </xsl:text>
					<xsl:copy-of select="$msg"/>
					<xsl:text> ]# </xsl:text>
					<br/>
				</font>
			</xsl:if>
		</xsl:if>
	</xsl:template>
	
	
</xsl:stylesheet>