IN THE NEXT LINE, REPLACE THE "#" WITH "?" AND YOU WILL GET THE CORRECT FIRST LINE OF THE FILE (THIS WAS PUT IN TO PREVENT IE FROM BEING "INTELLIGENT" AND TRYING TO PROCESS THIS FILE)
<#xml version="1.0" encoding="UTF-8"#>
<!DOCTYPE page [
	<!ENTITY % defs_env SYSTEM "defs_env.ent">
	%defs_env;
	<!ENTITY % defs_style SYSTEM "defs_layout.ent">
	%defs_style;
	<!ENTITY % defs_content SYSTEM "defs_content.ent">
	%defs_content;
]>
<xsl:stylesheet 
	version="1.0" 
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<!--xmlns:fo="http://www.w3.org/1999/XSL/Format"-->


<!-- ********************************************************************
		Copyright (c) Edward Maesen, 2002, San Francisco, CA, USA. All rights reserved.
     ******************************************************************** 

		This is a secondary stylesheet for web pages,
		containing definition of amazon specific templates, 
		referenced by the other stylesheets.
		
     ********************************************************************  
     ******************************************************************** -->



	<!-- 	***************************************************************** 
			global variables 
			***************************************************************** -->


	<!-- global defaults -->			

	<xsl:variable name="cellspacing" select="'10'"/>
		


	<!-- 	***************************************************************** 
			templates to process XML input and request amazon data.
			We have to use the uri templates that are defined in defs_env and 
			fill in the blanks...
			***************************************************************** -->
	
	<!-- single link to amazon product, based on asin; no product information retrieval -->
	
	<xsl:template match="amazonlink">
		<xsl:variable name="amazon_ass_asin_uri">
			<xsl:call-template name="_replace_substring">
				<xsl:with-param name="string">&amazon_ass_asin_uri_tmpl;</xsl:with-param>
				<xsl:with-param name="find" select="'[asin]'"/>
				<xsl:with-param name="replace" select="@asin"/>
			</xsl:call-template>
		</xsl:variable>
		<a href="{$amazon_ass_asin_uri}" target="float" 
			onclick="javascript: floatWindow
			('{$amazon_ass_asin_uri}','float','&float_width;','&float_height;'); 
			return false"><xsl:apply-templates/></a>
	</xsl:template>


	<!-- list of amazon products that require product information retrieval -->
	
	<xsl:template match="amazonproducts">
		<div class="subSection">
		<table border="0" width="100%" cellpadding="0" cellspacing="{$cellspacing}">
			<xsl:for-each select="amazonproduct">
				<xsl:apply-templates select="."/>
				<xsl:if test="position()!=last()">
					<tr>
						<td colspan="3" bgcolor="&divider_clr;"><img src="&spacerimg;" 
						 alt="" width="1" height="1" border="0"/></td>
					</tr>
					<tr>
						<td colspan="3"><img src="&spacerimg;" alt="" width="1" height="5" 
							border="0"/></td>	
					</tr>
				</xsl:if>
			</xsl:for-each>
		</table>
		</div>
	</xsl:template>


	<!-- single amazon product that requires product information retrieval -->
	
	<xsl:template match="amazonproduct">
		<xsl:variable name="productattributes" select="@*"/>
		<xsl:variable name="amazon_xml_asin_uri">
			<xsl:call-template name="_fill_in_the_blanks">
				<xsl:with-param name="tmpl_string">&amazon_xml_asin_uri_tmpl;</xsl:with-param>
				<xsl:with-param name="attributes" select="$productattributes"/>
			</xsl:call-template>
		</xsl:variable>

		<xsl:call-template name="_DEBUG">
			<xsl:with-param name="msg">
				<tr>
					<td colspan="3">
						amazon_xml_asin_uri_tmpl = &amazon_xml_asin_uri_tmpl;<br/>
						amazon_xml_asin_uri = <xsl:copy-of select="$amazon_xml_asin_uri"/>
					</td>
				</tr>
			</xsl:with-param>
		</xsl:call-template>

		<!-- call amazon's XML/HTTP web service to request for product information -->
		<xsl:variable name="productinfo" select="document($amazon_xml_asin_uri)/ProductInfo"/>

		<xsl:apply-templates select="$productinfo"/>
		<xsl:if test="not($productinfo)">
			<tr>
				<td colspan="3">
					<div class="error">
						&amazon_error_msg;
					</div>
				</td>
			</tr>
		</xsl:if>
		<xsl:if test="review | $productinfo">
			<tr>
				<td>&nbsp;</td>
				<td colspan="2">
					<span class="productReview">
						<xsl:apply-templates select="review"/>
					</span>
				</td>
			</tr>
		</xsl:if>
	</xsl:template>


	<!--  list of amazon products based on amazon's browse category ids: 
			requires product information retrieval -->
	
	<xsl:template match="amazoncataloglist">
		<xsl:variable name="searchattributes" select="@*"/>
		<xsl:variable name="amazon_xml_productlist_uri">
			<xsl:call-template name="_fill_in_the_blanks">
				<xsl:with-param name="tmpl_string">&amazon_xml_productlist_uri_tmpl;</xsl:with-param>
				<xsl:with-param name="attributes" select="$searchattributes"/>
			</xsl:call-template>
		</xsl:variable>

		<xsl:call-template name="_DEBUG">
			<xsl:with-param name="msg">
				<tr>
					<td colspan="3">
						amazon_xml_productlist_uri_tmpl = &amazon_xml_productlist_uri_tmpl;<br/>
						amazon_xml_productlist_uri = <xsl:copy-of select="$amazon_xml_productlist_uri"/>
					</td>
				</tr>
			</xsl:with-param>
		</xsl:call-template>

		<!-- call amazon's XML/HTTP web service to request for product information -->
		<xsl:variable name="productinfo" select="document($amazon_xml_productlist_uri)/ProductInfo"/>

		<xsl:call-template name="_show_productinfo">
			<xsl:with-param name="productinfo" select="$productinfo"/>
			<xsl:with-param name="ignore" select="@ignore"/>
		</xsl:call-template>
	</xsl:template>


	<!--  list of amazon products based on keyword search: 
			requires product information retrieval -->
	
	<xsl:template match="amazonkeywordslist">
		<!-- construct the amazon web service URL -->
		<xsl:variable name="searchattributes" select="@*"/>
		<xsl:variable name="amazon_xml_keywordsearchlist_uri">
			<xsl:call-template name="_fill_in_the_blanks">
				<xsl:with-param 
					name="tmpl_string">&amazon_xml_keywordsearchlist_uri_tmpl;</xsl:with-param>
				<xsl:with-param name="attributes" select="$searchattributes"/>
			</xsl:call-template>
		</xsl:variable>

		<xsl:call-template name="_DEBUG">
			<xsl:with-param name="msg">
				<tr>
					<td colspan="3">
						amazon_xml_keywordsearchlist_uri_tmpl = 
						&amazon_xml_keywordsearchlist_uri_tmpl;<br/>
						amazon_xml_keywordsearchlist_uri = <xsl:copy-of 
							select="$amazon_xml_keywordsearchlist_uri"/>
					</td>
				</tr>
			</xsl:with-param>
		</xsl:call-template>

		<!-- call amazon's XML/HTTP web service to request for product information -->
		<xsl:variable name="productinfo" 
			select="document($amazon_xml_keywordsearchlist_uri)/ProductInfo"/>

		<!-- transform the data send back by amazon -->
		<xsl:call-template name="_show_productinfo">
			<xsl:with-param name="productinfo" select="$productinfo"/>
			<xsl:with-param name="ignore" select="@ignore"/>
		</xsl:call-template>
	</xsl:template>


	<!-- named template for the display of product information -->
	
	<xsl:template name="_show_productinfo">
		<xsl:param name="productinfo"/>
		<xsl:param name="ignore"/>
		<div class="subSection">
			<table border="0" width="100%" cellpadding="0" cellspacing="{$cellspacing}">
				<!-- transform the product information -->
				<xsl:apply-templates select="$productinfo" mode="withdivider">
					<xsl:with-param name="ignore" select="$ignore"/>
				</xsl:apply-templates>
				<!-- show an error message in case no product information was returned -->	
				<xsl:if test="not($productinfo)">
					<tr>
						<td colspan="3">
							<div class="error">
								&amazon_error_msg;
							</div>
						</td>
					</tr>
				</xsl:if>
			</table>
		</div>
	</xsl:template>
	
	

	<!-- 	***************************************************************** 
			templates to process amazon data - for lite data
			***************************************************************** -->

	<xsl:template match="ProductInfo" mode="withdivider">
		<xsl:param name="ignore" select="''"/>
		<xsl:for-each select="Details">
			<xsl:if test="not($ignore!='' and contains(ProductName,$ignore))">
				<xsl:apply-templates select="."/>
				<xsl:if test="position()!=last()">
					<tr>
						<td colspan="3" bgcolor="&divider_clr;"><img src="&spacerimg;" 
						 alt="" width="1" height="1" border="0"/></td>
					</tr>	
				</xsl:if>
			</xsl:if>
		</xsl:for-each>
	</xsl:template>

	<xsl:template match="ProductInfo">
		<xsl:apply-templates select="Details"/>
	</xsl:template>

	<xsl:template match="Details">
		<tr>
			<td>
				<img src="{ImageUrlSmall}"/>
			</td>
			<td>
				<div class="productTitle"><xsl:value-of select="ProductName"/></div>
				<div class="productDetail">
					<xsl:if test="normalize-space(Catalog/text())">
						<xsl:text>(</xsl:text>
						<xsl:value-of select="Catalog"/>
						<xsl:text>) </xsl:text>
					</xsl:if>
					<xsl:apply-templates select="Authors"/>
					<xsl:if test="not(Authors)"><br/></xsl:if>
					
					<b>&amazon_published_str; </b>
					<xsl:value-of select="ReleaseDate"/>
					<br/>

					<xsl:call-template name="_Price">
						<xsl:with-param name="OurPrice" select="substring(OurPrice, 2)"/>
						<xsl:with-param name="ListPrice" select="substring(ListPrice, 2)"/>
					</xsl:call-template>
					<br/>

					<xsl:variable name="amazon_ass_asin_uri">
						<xsl:call-template name="_replace_substring">
							<xsl:with-param name="string">&amazon_ass_asin_uri_tmpl;</xsl:with-param>
							<xsl:with-param name="find" select="'[asin]'"/>
							<xsl:with-param name="replace" select="string(Asin)"/>
						</xsl:call-template>
					</xsl:variable>

					<xsl:call-template name="_DEBUG">
						<xsl:with-param name="msg">
							amazon_ass_asin_uri_tmpl = &amazon_ass_asin_uri_tmpl;<br/>
							amazon_ass_asin_uri = <xsl:copy-of select="$amazon_ass_asin_uri"/>
						</xsl:with-param>
					</xsl:call-template>

					<a href="{$amazon_ass_asin_uri}" target="float" 
						onclick="javascript: floatWindow
						('{$amazon_ass_asin_uri}','float','&float_width;','&float_height;'); 
						return false">&amazon_read_more_str;</a>

				</div>

        </td>
        <td>
				<xsl:call-template name="_BuyButton">
					<xsl:with-param name="Asin" select="Asin"/>
				</xsl:call-template>
        </td>
      </tr>
	</xsl:template>

	<xsl:template name="_Price">
		<xsl:param name="OurPrice"  select="'$1.00'"/>
		<xsl:param name="ListPrice" select="'$1.00'"/>

		<xsl:choose>
			<xsl:when test="$OurPrice = $ListPrice">
				<b>&amazon_price_str; </b>
				&amazon_currency_str;<xsl:value-of select="$OurPrice"/>
			</xsl:when>
			<xsl:otherwise>
				<!--
				<b>List price: </b>
				$<xsl:value-of select="$ListPrice"/>
				<br/>
				-->
				<b>&amazon_price_str; </b>
				&amazon_currency_str;<xsl:value-of select="$OurPrice"/>
				<xsl:text> (</xsl:text>
				<xsl:value-of select="100 - round(($OurPrice div $ListPrice) * 100)"/>
				<xsl:text>&amazon_perc_off_str;)</xsl:text>
				<xsl:if test="$ext='.html'">
					<span class="comment"> &amazon_price_msg;</span>
				</xsl:if>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

	<xsl:template match="Authors">
		<xsl:text>&amazon_by_str; </xsl:text>
		<xsl:for-each select="Author">
			<xsl:value-of select="."/>
			<xsl:choose>
				<xsl:when test="position()=last()"><br/></xsl:when>
				<xsl:when test="position()=last()-1"> &amazon_and_str; </xsl:when>
				<xsl:otherwise>, </xsl:otherwise>
			</xsl:choose>
		</xsl:for-each>
	</xsl:template>

	<xsl:template name="_BuyButton">
		<xsl:param name="Asin"/>
		<form method="POST" 
			action="{concat('http://www.amazon.com/o/dt/assoc/handle-buy-box=', 
							$Asin)}" target="float" 
			onsubmit="javascript: floatWindow
							('about:blank','float','&float_width;','&float_height;'); 
							return true">
			<input type="hidden" name="{concat('asin.', $Asin)}" value="1"/>
			<input type="hidden" name="tag_value" value="&amazon_ass_id;"/>
			<input type="hidden" name="tag-value" value="&amazon_ass_id;"/>
			<input type="hidden" name="dev-tag-value" value="&amazon_dev_token;"/>
			<!--
   	   <input type="Submit" value="Buy From Amazon" name="submit.add-to-cart"/>
			-->
			<!-- use fake "a" tag to allow for a:hover CSS effect on input image -->
			<a href="javascript: return false();">
				<input type="image" value="Buy From Amazon.com" name="submit.add-to-cart" 
					src="&amazon_buy_img;" width="140" height="20" border="0" 
					alt="Buy From Amazon"/>
			</a>
		</form>
	</xsl:template>



	<!-- 	***************************************************************** 
			miscellaneous templates 
			***************************************************************** -->



</xsl:stylesheet>